mqttfastledmenu/mqttfastledmenu.ino

#include "mqttfastledmenu.h"

#include <FastLED.h>
#include <ESP8266WiFi.h>
#include <PubSubClient.h>

// LED
int brightness = LED_BRIGHTNESS_DEFAULT;
int color = LED_COLOR_DEFAULT;
int speed = LED_SPEED_DEFAULT;
CRGB leds[LED_NUM];
int ledEffect = LED_EFFECT_OFF;

// WIFI
WiFiClient espClient;

// MQTT
char message_buff[100];
PubSubClient client(espClient);

void setup() { 
  Serial.begin(SERIAL_SPEED);
  Serial.println("\nresetting");
  
  // WIFI
  setupWifi();
  
  // MQTT
  client.setServer(MQTT_SERVER, MQTT_PORT);
  client.setCallback(callbackMQTT);
  testConnectMQTT();
  client.subscribe(MQTT_LED_EFFECT);
  client.subscribe(MQTT_LED_BRIGHTNESS);
  client.subscribe(MQTT_LED_COLOR);
  client.subscribe(MQTT_LED_SPEED);
  
  // LED
  LEDS.addLeds<LED_CHIPSET,LED_PIN, LED_COLOR_ORDER>(leds, LED_NUM).setCorrection(TypicalSMD5050);
  FastLED.setBrightness(brightness);
  ledBlackAll();
}

// WIFI
void setupWifi() {
  Serial.print("Connexion a ");
  Serial.print(WIFI_SSID);
  WiFi.mode(WIFI_STA);
  WiFi.begin(WIFI_SSID, WIFI_PASSWORD);
  
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  
  Serial.println();
  Serial.print("IP : ");
  Serial.println(WiFi.localIP());
}

// MQTT
void testConnectMQTT() {
  while (!client.connected()) {
    Serial.print("Connexion au serveur MQTT... ");
    if (client.connect("ESP8266Client", MQTT_USER, MQTT_PASS)) {
      // TODO : doit-on se reconnecter aux topics ?
      Serial.println("OK");
    } else {
      Serial.print("KO, erreur : ");
      Serial.print(client.state());
      Serial.println(", on attend 5 secondes avant de recommencer");
      delay(5000);
    }
  }
}

// Déclenche les actions à la réception d'un message
void callbackMQTT(char* topic, byte* payload, unsigned int length) {
  if (String(topic) == MQTT_LED_EFFECT) {
    Serial.print("Received [" + String(topic) + "] : ");
    
    Serial.print(payload[0]);
    Serial.print(" ~ ");
    Serial.print(payload[0] - '0');
    
    ledEffect = payload[0] - '0';
    Serial.print("[");
    Serial.print(ledEffect);
    Serial.println("]");
    
    // Si on ne repasse pas tout à noir, cela peut faire des effets surprenants
    ledBlackAll();
  } else if (String(topic) == MQTT_LED_BRIGHTNESS) {
    unsigned int i = 0;
    for(i = 0; i < length; i++) {
      message_buff[i] = payload[i];
    }
    message_buff[i] = '\0';
    // TODO : il est surement possible de faire plus propre
    String msgString = String(message_buff);
    brightness = msgString.toInt();
    FastLED.setBrightness(brightness);

    Serial.print("Received [" + String(topic) + "] : ");
    Serial.println(msgString);
  } else if (String(topic) == MQTT_LED_COLOR) {
    unsigned int i = 0;
    for(i = 0; i < length; i++) {
      message_buff[i] = payload[i];
    }
    message_buff[i] = '\0';
    String msgString = String(message_buff);
    color = msgString.toInt();
    Serial.print("Received [" + String(topic) + "] : ");
    Serial.println(msgString);
  } else if (String(topic) == MQTT_LED_SPEED) {
    unsigned int i = 0;
    for(i = 0; i < length; i++) {
      message_buff[i] = payload[i];
    }
    message_buff[i] = '\0';
    String msgString = String(message_buff);
    speed = msgString.toInt();
    Serial.print("Received [" + String(topic) + "] : ");
    Serial.println(msgString);
  }
}

// LED
void ledBlackAll()
{
    FastLED.clear();
    FastLED.show();
    FastLED.delay(1000 / speed); 
}

void ledCylon()
{
    // Effet cylon : on allume une led, on attends, on eteinds, on passe à la suivante
    // TODO : trop d'attente entre les clients.loop !!!!
    for(int i = 0; i < LED_NUM; i++) {
      if ((i % 10) == 0) {
          client.loop();
          if (ledEffect != LED_EFFECT_CYLON) {
            return;
          }
      }
      
      leds[i] = color;
      FastLED.show(); 
      FastLED.delay(1000 / speed); 
      leds[i] = CRGB::Black;
      FastLED.show(); 
      FastLED.delay(1000 / speed);
    }
    for(int i = LED_NUM - 1; i > 0; i--) {
      if ((i % 10) == 0) {
          client.loop();
          if (ledEffect != LED_EFFECT_CYLON) {
            return;
          }
      }
      
      leds[i] = color;
      FastLED.show(); 
      FastLED.delay(1000 / speed); 
      leds[i] = CRGB::Black;
      FastLED.show();
    }
    FastLED.delay(1000 / speed);
}

void ledError()
{
    for(int i = 0; i < LED_NUM; i++) {
      if ((i % 2) == 0) {
          leds[i] = CRGB::Black;
      } else {
          leds[i] = color;
      }
    }

    FastLED.show(); 
    FastLED.delay(1000 / speed); 
}

// TODO : ne doit pas rester à terme, ça ne sert à rien de garder une fonction comme ça
void ledFullRed()
{
    fill_solid(leds, LED_NUM, color);
    FastLED.show();
    FastLED.delay(1000 / speed); 
}

void loop() {
  // MQTT
  testConnectMQTT();
  client.loop();
  
  EVERY_N_SECONDS(180) {
    Serial.print("MQTT Subscribe refresh");
    client.subscribe(MQTT_LED_EFFECT);
    client.subscribe(MQTT_LED_BRIGHTNESS);
    client.subscribe(MQTT_LED_COLOR);
    client.subscribe(MQTT_LED_SPEED);
    Serial.println(" done");
  }
  
  // LED
  switch(ledEffect)
  {
      case LED_EFFECT_OFF:
          ledBlackAll();
          break;
      case LED_EFFECT_CYLON:
          ledCylon();
          break;
      case LED_EFFECT_FULLRED:
          ledFullRed();
          break;
      default:
          ledError();
          break;
  }
}

// TODO : regrouper input et select en un seul group, l'input enverrait directement Off et les effets ne seraient que effets